title-group: make rebface [
	tip:	{
		USAGE:
			title-group %images/setup.png data "Title" "Body"

		DESCRIPTION:
			A title and text with an optional image to the left.
			If an image is specified then height is set to image height.
	}
	font:	default-font-top
	rebind:	make function! [] [
		font/name: effects/font
		font/size: sizes/font
	]
	init:	make function! [/local p indent] [
		indent: either image [size/y: image/size/y image/size/x + sizes/line] [sizes/line]
		p: self
		;	create title text
		pane: make subface [
			offset: as-pair indent sizes/line
			size:	as-pair p/size/x - indent - sizes/line 10000
			text:	p/data
			font:	make default-font-bold [size: to integer! sizes/font / .75]
			para:	default-para-wrap
		]
		pane/size: 5x5 + size-text pane
		;	create body text
		para: make default-para-wrap compose [
			origin:	(as-pair indent p/pane/size/y + sizes/line + sizes/line)
			margin:	(as-pair sizes/line 0)
		]
		;	auto-height?
		all [not image negative? size/y size/y: 10000 size/y: para/origin/y + second size-text self]
		data: none
	]
]