root/trunk/orca/rebol_compat.r

; REBOL compatibility functions
;
; Enable rebol in config.r to include these.


add:        func [a [number!] b [number!]] [a + b]
subtract:   func [a [number!] b [number!]] [a - b]
divide:     func [a [number!] b [number!]] [a / b]
multiply:   func [a [number!] b [number!]] [a * b]
zero?:      func [value] [0 = value]
negative?:  func [value [number!]] [value < 0]
positive?:  func [value [number!]] [value > 0]
not-equal?: func [v1 v2] [not :v1 = :v2]

any-function?: func [tst] [
    any [
        function? :tst
        native? :tst
        op? :tst
    ]
]

array: func [
    size [number! block!]
    /initial init
    /local init2 s
][
    size: insert copy [] size
    while [not head? size] [
        size: back size
        s: first size
        s: to-integer s
        if series? init [init: copy init]
        init2: init
        init: copy []
        loop s [
            append/only init init2
        ]
    ]
    init
]

help: ?: func [
    "Help Function"
    'word [word!] "What do you need help for"
    /local fun descr start
][
    if not value? word [
        print [word "has no value"]
        exit
    ]
    if any-function? get/any word [
        fun: get word
        foreach w second load mold :fun [
            if string? :w [descr: w]
            if any-word? :w [break]
        ]
        either descr [
            print descr
        ][
            print "(not documented)"
        ]
        prin "ARGS:"
        foreach w second load mold :fun [
            either refinement? :w [
                print ""
                print ""
                prin [" " w]
                start: yes
            ] [
            if any-word? :w [
                print ""
                prin ["    " w "^-"]
                start: yes
            ]]
            if all [string? :w start] [
                prin w
            ]
        ]
        print ""
        if not start [
            print "    NO ARGS"
        ]
    ]
    exit
]


;eof