root/trunk/m2/m2_cygwin.r

REBOL [
    Title: "m2 Cygwin template"
]


win32: func [blk] [do blk]

console: does [ m2/ct/cfg_console: true ]

eol: "^/" 

dist_files: function [] [str obj] [
    str: make string! 64

    obj: []
    foreach t m2/targets [ append obj t/objdir ]
    obj: intersect obj obj   ; Removes duplicates.
    append str obj

    foreach t m2/targets [ append str t/dist ]
    str
]

generate_makefile: does [
    foreach t m2/targets [
        ;probe t

        ; make_obj_rule must be called before we write DIST_FILES since
        ; it finds the header dependencies.
        t/built_obj_rule: t/make_obj_rule
    ]

    emit do_tags copy cygwin_header

    emit "^/#------ Target settings"
    foreach t m2/targets [ emit "^/^/" t/macro_text ]

    emit [ {^/ARCHIVE = } m2/project_version {^/DIST_FILES = \^/} ]
    if not empty? m2/distribution_files [
        emit expand_list_gnu/part m2/distribution_files
    ]
    emit expand_list_gnu m2/header_files_used

    emit "^/^/#------ Build rules^/^/all:"
    foreach t m2/targets [ emit [ " " t/output_file ] ]
    emit eol

    foreach t m2/targets [ emit " " t/rule_text ]

    emit [ "^/^/" do_tags copy gnu_other_rules ]

    foreach t m2/targets [ emit t/clean ]

    emit "^/^/#------ Compile rules^/^/"
    foreach t m2/targets [
        emit t/built_obj_rule
        if t/cfg/qt [ emit t/moc_rule ]
    ]

    emit "^/#EOF^/"
]


qt-includes: context [
   gui:     does [ include_from {$(QTDIR)\include\QtGui} ]
   network: does [ include_from {$(QTDIR)\include\QtNetwork} ]
   opengl:  does [ include_from {$(QTDIR)\include\QtOpenGL} ]
   xml:     does [ include_from {$(QTDIR)\include\QtXml} ]
   svg:     does [ include_from {$(QTDIR)\include\QtSvg} ]
   sql:     does [ include_from {$(QTDIR)\include\QtSql} ]
   support: does [ include_from {$(QTDIR)\include\Qt3Support}
                   cxxflags {-DQT3_SUPPORT} ]
]

qt-libraries: context [
   core:    { QtCore4}
   gui:     { QtGui4}
   network: { QtNetwork4}
   opengl:  { QtOpenGL4}
   xml:     { QtXml4}
   svg:     { QtSvg4}
   sql:     { QtSql4}
   support: { Qt3Support4}
   main:    { qtmain}
]

qt-debug-libraries: context [
   core:    { QtCored4}
   gui:     { QtGuid4}
   network: { QtNetworkd4}
   opengl:  { QtOpenGLd4}
   xml:     { QtXmld4}
   xml:     { QtXmld4}
   svg:     { QtSvgd4}
   sql:     { QtSqld4}
   support: { Qt3Supportd4}
   main:    { qtmaind}
]


exe_target: make m2/target_env
[
    ; built_obj_rule exists only to hold the output make_obj_rule
    built_obj_rule: none

    obj_macro: none
    cfg_console: false

    config:
    [
        obj_macro: rejoin [ "$(" uppercase copy name "_OBJECTS)" ]

        cflags {-pipe}

        cflags {-mno-cygwin}
        lflags {-mno-cygwin}

        if cfg/warn [
            cflags {-Wall -W}
        ]

        if cfg/debug [
            cflags {-g -DDEBUG}
        ]

        if cfg/release [
            cflags {-O3 -DNDEBUG}
        ]

        if not cfg_console [
            cflags {-mwindows}
            lflags {-mwindows}
        ]

        if cfg/opengl [
            libs {opengl32 glu32}
        ]

        if cfg/qt [
            either cfg/qt = 3 [
                include_from {$(QTDIR)\include}
            ][
                include_from {$(QTDIR)\include}
                include_from {$(QTDIR)\include\QtCore}
                do bind cfg/qt in qt-includes 'gui
            ]
            if cfg/release [
                cxxflags {-DQT_NO_DEBUG}
            ]
        ]

        if cfg/x11 [
            include_from {/usr/X11R6/include}
            libs_from %/usr/X11R6/lib {Xext X11 m}
        ]
    ]

    configure: does [
        output_file: rejoin [ output_dir name ".exe" ]
        do config
        if cfg/qt [
            either cfg/qt = 3 [
                ;libs_from {$(QTDIR)\lib} {qt}
                ;libs_from {$(QTDIR)\lib} {qt-mt331 qtmain}
                libs_from {$(QTDIR)\lib} {qt-mt qtmain}

                ; If Qt statically compiled must link with more libs.
                libs {ole32 comdlg32 winspool advapi32 imm32 ws2_32 shell32}
            ][
                append qt4-libs: copy cfg/qt [core main]
                
                libs_from %"$(QTDIR)/lib" 
                    rejoin bind qt4-libs either cfg/debug
                            [in qt-debug-libraries 'gui]
                            [in qt-libraries 'gui]

                libs {comdlg32 winspool advapi32 shell32 ole32}
            ]
        ]
    ]

    macro_text: func []
    [
        emit [
            uc_name "_CFLAGS   = " menv_cflags " " gnu_string "-D" defines eol
            uc_name "_CXXFLAGS = $(" uc_name "_CFLAGS) " menv_cxxflags eol
            uc_name "_INCPATH  = " gnu_string "-I" include_paths eol
            uc_name "_LFLAGS   = " menv_lflags eol
            uc_name "_LIBS     = " gnu_string "-L" link_paths " "
                              gnu_string "-l" link_libs eol
        ]

        ;if cfg/qt [
        ;    emit [
        ;        uc_name "_SRCMOC  = " expand_list_gnu srcmoc_files eol
        ;        uc_name "_OBJMOC  = " expand_list_gnu objmoc_files eol
        ;    ]
        ;]

        emit [
            ;uc_name "_HEADERS  = " expand_list_gnu header_files eol
            uc_name "_SOURCES  = " expand_list_gnu source_files eol
            uc_name "_OBJECTS  = " expand_list_gnu object_files eol
        ]
    ]

    clean: does [ rejoin [ "^(tab)-rm -f " output_file " " obj_macro eol ] ]
    ; TODO: if cfg/qt [ "rm -f $(_SRCMOC)" ]

    dist: function [] [uc_name] [
        uc_name: uppercase name
        rejoin [" $(" uc_name "_SOURCES)" ]
    ]

    rule_text: func []
    [
        emit [ eol output_file ": " obj_macro m2/local_libs link_libs
            {^/^(tab)$(LINK) -o $@ $(} uc_name {_LFLAGS) } obj_macro
            { $(} uc_name {_LIBS)} eol
        ]
    ]
]


lib_target: make exe_target [
    configure: does [
        output_file: rejoin [ output_dir "lib" name ".a" ]
        do config
    ]

    rule_text: function [] []
    [
        emit [ eol output_file ": " obj_macro
            "^/^(tab)ar rc $@ " obj_macro " $(" uppercase name "_LFLAGS)"
            "^/^(tab)ranlib $@^/"
        ]
    ]
]


shlib_target: make exe_target [
    configure: does [
        output_file: rejoin [ output_dir name ".dll" ]
        do config
        ;cflags {-fPIC}
        lflags rejoin [{-shared -Wl,--out-implib,} output_dir "lib" name ".a"]
    ]
]


cygwin_header:
{#----------------------------------------------------------------------------
# Makefile for Cygwin
# Generated by m2 at <now>
# Project: <m2/project_name>
#----------------------------------------------------------------------------


#------ Compiler and tools

CC       = gcc
CXX      = g++
LINK     = g++
TAR      = tar -cf
GZIP     = gzip -9f
MOC      = $(QTDIR)/bin/moc

}
;#------ Project-wide settings


gnu_other_rules:
{<m2/makefile>: <project_file>
^(tab)m2 <project_file>

.PHONY: dist
dist:
^(tab)$(TAR) $(ARCHIVE).tar --exclude CVS --exclude .svn --exclude *.o <project_file> <dist_files> $(DIST_FILES)
^(tab)mkdir /tmp/$(ARCHIVE)
^(tab)tar -C /tmp/$(ARCHIVE) -xf $(ARCHIVE).tar
^(tab)tar -C /tmp -cf $(ARCHIVE).tar $(ARCHIVE)
^(tab)rm -rf /tmp/$(ARCHIVE)
^(tab)$(GZIP) $(ARCHIVE).tar

.PHONY: clean
clean:
^(tab)-rm -f core
}


;EOF